Arduino Smart Parking Assistant Using Arduino Nano and HC-SR04

Arduino Smart Parking Assistant Code

Now it is time to program the Arduino Nano.

If you have not already installed it, download the Arduino IDE from the official Arduino website: https://www.arduino.cc/en/software

Open the Arduino IDE and create a new sketch. Replace the existing code with the following program.

const int trigPin = 9;
const int echoPin = 10;

const int greenLED  = 4;
const int yellowLED = 5;
const int redLED    = 6;
const int buzzer    = 3;

unsigned long previousBeep = 0;
bool buzzerState = false;

float getDistance() {
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);

  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);

  unsigned long duration =
      pulseIn(echoPin, HIGH, 30000UL);

  if (duration == 0) {
    return -1;  // No valid echo
  }

  return duration * 0.0343 / 2.0;
}

void allOff() {
  digitalWrite(greenLED, LOW);
  digitalWrite(yellowLED, LOW);
  digitalWrite(redLED, LOW);
  digitalWrite(buzzer, LOW);

  buzzerState = false;
}

void setup() {
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);

  pinMode(greenLED, OUTPUT);
  pinMode(yellowLED, OUTPUT);
  pinMode(redLED, OUTPUT);
  pinMode(buzzer, OUTPUT);

  Serial.begin(9600);

  allOff();
}

void loop() {
  float distance = getDistance();

  Serial.print("Distance: ");

  if (distance < 0) {
    Serial.println("No valid echo");
    allOff();
  }
  else {
    Serial.print(distance);
    Serial.println(" cm");

    if (distance > 50) {
      allOff();
      digitalWrite(greenLED, HIGH);
    }
    else if (distance > 20) {
      allOff();
      digitalWrite(yellowLED, HIGH);
    }
    else if (distance >= 10) {
      digitalWrite(greenLED, LOW);
      digitalWrite(yellowLED, LOW);
      digitalWrite(redLED, HIGH);

      unsigned long now = millis();

      if (now - previousBeep >= 500) {
        previousBeep = now;
        buzzerState = !buzzerState;
        digitalWrite(buzzer, buzzerState);
      }
    }
    else {
      digitalWrite(greenLED, LOW);
      digitalWrite(yellowLED, LOW);
      digitalWrite(redLED, HIGH);

      unsigned long now = millis();

      if (now - previousBeep >= 120) {
        previousBeep = now;
        buzzerState = !buzzerState;
        digitalWrite(buzzer, buzzerState);
      }
    }
  }

  delay(50);